1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
|
/*
* OpenRISC string.S
*
* Linux architectural port borrowing liberally from similar works of
* others. All original copyrights apply as per the original source
* declaration.
*
* Modifications for the OpenRISC architecture:
* Copyright (C) 2003 Matjaz Breskvar <phoenix@bsemi.com>
* Copyright (C) 2010-2011 Jonas Bonn <jonas@southpole.se>
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version
* 2 of the License, or (at your option) any later version.
*/
#include <linux/linkage.h>
#include <asm/errno.h>
/*
* this can be optimized by doing gcc inline assemlby with
* proper constraints (no need to save args registers...)
*
*/
/*
*
* int __copy_tofrom_user(void *to, const void *from, unsigned long size);
*
* NOTE: it returns number of bytes NOT copied !!!
*
*/
.global __copy_tofrom_user
__copy_tofrom_user:
l.addi r1,r1,-12
l.sw 0(r1),r6
l.sw 4(r1),r4
l.sw 8(r1),r3
l.addi r11,r5,0
2: l.sfeq r11,r0
l.bf 1f
l.addi r11,r11,-1
8: l.lbz r6,0(r4)
9: l.sb 0(r3),r6
l.addi r3,r3,1
l.j 2b
l.addi r4,r4,1
1:
l.addi r11,r11,1 // r11 holds the return value
l.lwz r6,0(r1)
l.lwz r4,4(r1)
l.lwz r3,8(r1)
l.jr r9
l.addi r1,r1,12
.section .fixup, "ax"
99:
l.j 1b
l.nop
.previous
.section __ex_table, "a"
.long 8b, 99b // read fault
.long 9b, 99b // write fault
.previous
/*
* unsigned long clear_user(void *addr, unsigned long size) ;
*
* NOTE: it returns number of bytes NOT cleared !!!
*/
.global __clear_user
__clear_user:
l.addi r1,r1,-8
l.sw 0(r1),r4
l.sw 4(r1),r3
2: l.sfeq r4,r0
l.bf 1f
l.addi r4,r4,-1
9: l.sb 0(r3),r0
l.j 2b
l.addi r3,r3,1
1:
l.addi r11,r4,1
l.lwz r4,0(r1)
l.lwz r3,4(r1)
l.jr r9
l.addi r1,r1,8
.section .fixup, "ax"
99:
l.j 1b
l.nop
.previous
.section __ex_table, "a"
.long 9b, 99b // write fault
.previous
/*
* long strncpy_from_user(char *dst, const char *src, long count)
*
*
*/
.global __strncpy_from_user
__strncpy_from_user:
l.addi r1,r1,-16
l.sw 0(r1),r6
l.sw 4(r1),r5
l.sw 8(r1),r4
l.sw 12(r1),r3
l.addi r11,r5,0
2: l.sfeq r5,r0
l.bf 1f
l.addi r5,r5,-1
8: l.lbz r6,0(r4)
l.sfeq r6,r0
l.bf 1f
9: l.sb 0(r3),r6
l.addi r3,r3,1
l.j 2b
l.addi r4,r4,1
1:
l.lwz r6,0(r1)
l.addi r5,r5,1
l.sub r11,r11,r5 // r11 holds the return value
l.lwz r6,0(r1)
l.lwz r5,4(r1)
l.lwz r4,8(r1)
l.lwz r3,12(r1)
l.jr r9
l.addi r1,r1,16
.section .fixup, "ax"
99:
l.movhi r11,hi(-EFAULT)
l.ori r11,r11,lo(-EFAULT)
l.lwz r6,0(r1)
l.lwz r5,4(r1)
l.lwz r4,8(r1)
l.lwz r3,12(r1)
l.jr r9
l.addi r1,r1,16
.previous
.section __ex_table, "a"
.long 8b, 99b // read fault
.previous
/*
* extern int __strnlen_user(const char *str, long len, unsigned long top);
*
*
* RTRN: - length of a string including NUL termination character
* - on page fault 0
*/
.global __strnlen_user
__strnlen_user:
l.addi r1,r1,-8
l.sw 0(r1),r6
l.sw 4(r1),r3
l.addi r11,r0,0
2: l.sfeq r11,r4
l.bf 1f
l.addi r11,r11,1
8: l.lbz r6,0(r3)
l.sfeq r6,r0
l.bf 1f
l.sfgeu r3,r5 // are we over the top ?
l.bf 99f
l.j 2b
l.addi r3,r3,1
1:
l.lwz r6,0(r1)
l.lwz r3,4(r1)
l.jr r9
l.addi r1,r1,8
.section .fixup, "ax"
99:
l.addi r11,r0,0
l.lwz r6,0(r1)
l.lwz r3,4(r1)
l.jr r9
l.addi r1,r1,8
.previous
.section __ex_table, "a"
.long 8b, 99b // read fault
.previous
|
