1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
/*
* __get_user functions.
*
* (C) Copyright 1998 Linus Torvalds
*
* These functions have a non-standard call interface
* to make them more efficient, especially as they
* return an error value in addition to the "real"
* return value.
*/
#include <linux/linkage.h>
#include <asm/dwarf2.h>
#include <asm/thread_info.h>
/*
* __get_user_X
*
* Inputs: %eax contains the address
*
* Outputs: %eax is error code (0 or -EFAULT)
* %edx contains zero-extended value
*
* These functions should not modify any other registers,
* as they get called from within inline assembly.
*/
.text
ENTRY(__get_user_1)
CFI_STARTPROC
GET_THREAD_INFO(%edx)
cmp TI_addr_limit(%edx),%eax
jae bad_get_user
1: movzb (%eax),%edx
xor %eax,%eax
ret
CFI_ENDPROC
ENDPROC(__get_user_1)
ENTRY(__get_user_2)
CFI_STARTPROC
add $1,%eax
jc bad_get_user
GET_THREAD_INFO(%edx)
cmp TI_addr_limit(%edx),%eax
jae bad_get_user
2: movzwl -1(%eax),%edx
xor %eax,%eax
ret
CFI_ENDPROC
ENDPROC(__get_user_2)
ENTRY(__get_user_4)
CFI_STARTPROC
add $3,%eax
jc bad_get_user
GET_THREAD_INFO(%edx)
cmp TI_addr_limit(%edx),%eax
jae bad_get_user
3: mov -3(%eax),%edx
xor %eax,%eax
ret
CFI_ENDPROC
ENDPROC(__get_user_4)
bad_get_user:
CFI_STARTPROC
xor %edx,%edx
mov $-14,%eax
ret
CFI_ENDPROC
END(bad_get_user)
.section __ex_table,"a"
.long 1b,bad_get_user
.long 2b,bad_get_user
.long 3b,bad_get_user
.previous
|
