1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
#########################################################################
# #
# OCaml #
# #
# Damien Doligez, projet Gallium, INRIA Rocquencourt #
# #
# Copyright 2013 Institut National de Recherche en Informatique et #
# en Automatique. All rights reserved. This file is distributed #
# under the terms of the Q Public License version 1.0. #
# #
#########################################################################
function check() {
if (!in_test){
printf("error at line %d: found test result without test start\n", NR);
errored = 1;
}
}
function clear() {
curfile = "";
in_test = 0;
}
function record_pass() {
check();
++ passed;
clear();
}
function record_skip() {
check();
++ skipped;
clear();
}
function record_fail() {
check();
++ failed;
fail[failidx++] = sprintf ("%s/%s", curdir, curfile);
clear();
}
function record_unexp() {
++ unexped;
unexp[unexpidx++] = sprintf ("%s/%s", curdir, curfile);
clear();
}
/Running tests from '[^']*'/ {
if (in_test) record_unexp();
match($0, /Running tests from '[^']*'/);
curdir = substr($0, RSTART+20, RLENGTH - 21);
curfile = "";
}
/ ... testing.* ... testing/ {
printf("error at line %d: found two test results on the same line\n", NR);
errored = 1;
}
/^ ... testing '[^']*'/ {
if (in_test) record_unexp();
match($0, /... testing '[^']*'/);
curfile = substr($0, RSTART+13, RLENGTH-14);
in_test = 1;
}
/^ ... testing with / {
if (in_test) record_unexp();
in_test = 1;
}
/=> passed/ {
record_pass();
}
/=> skipped/ {
record_skip();
}
/=> failed/ {
record_fail();
}
/=> unexpected error/ {
record_unexp();
}
# Not displaying "skipped" for the moment, as most of the skipped tests
# print nothing at all and are not counted.
END {
if (errored){
printf ("\n#### Some fatal error occurred during testing.\n\n");
exit (3);
}else{
printf("\n");
printf("Summary:\n");
printf(" %3d test(s) passed\n", passed);
printf(" %3d test(s) failed\n", failed);
printf(" %3d unexpected error(s)\n", unexped);
if (failed != 0){
printf("\nList of failed tests:\n");
for (i=0; i < failed; i++) printf(" %s\n", fail[i]);
}
if (unexped != 0){
printf("\nList of unexpected errors:\n");
for (i=0; i < unexped; i++) printf(" %s\n", unexp[i]);
}
printf("\n");
if (failed || unexped){
printf("#### Some tests failed. Exiting with error status.\n\n");
exit 4;
}
}
}
|
